视频合集

附件：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
************************ 计算家庭子女数 ************************
** 方法一：来自childproxy 库
cd "C:\Users\wugan\Desktop\CFPS-中国家庭追踪调查（2010-2020）\CFPS2018\data"
use "cfps2018childproxy_202012.dta", clear
** 计算孩子数量:gen——replace; egen——ereplace
ssc install ereplace, replace
egen male_size=count(fid18) if gender_update==1, by(fid18)
ereplace male_size=mean(male_size), by(fid18)   // mean 函数补充缺失值——分组后，每组内有取值的变量取值都是一样的
replace male_size=0 if male_size==.
egen female_size=count(fid18) if gender_update==0, by(fid18)
ereplace female_size=mean(female_size), by(fid18)
replace female_size=0 if female_size==.
// 男孩+女孩
egen child_num=rowtotal(male_size female_size)

// 删除重复样本
duplicates drop fid18, force
keep fid18 male_size female_size child_num
save "merge_data__child",replace

use "cfps2018famecon_202101",clear
merge 1:1 fid18 using "merge_data__child"
drop if _merge==2
replace male_size=0 if _merge==1   // 补充数据——将未匹配成功的家庭的子女数改为0
replace female_size=0 if _merge==1
replace child_num=0 if _merge==1
drop _merge
save "cfps2018famecon",replace

** 方法二：来自famconf库
use "cfps2018famconf_202008.dta",clear
gen member_age=2018-tb1y_a_p if tb1y_a_p!=-1 & tb1y_a_p!=-9  // 排除缺失与不知道的情况
** 计算孩子数量
egen male_size2=count(fid18) if tb2_a_p==1 & member_age<=15, by(fid18)
ereplace male_size2=mean(male_size2), by(fid18)
replace male_size2=0 if male_size2==.
egen female_size2=count(fid18) if tb2_a_p==0 & member_age<=15, by(fid18)
ereplace female_size2=mean(female_size2), by(fid18)
replace female_size2=0 if female_size2==.
// 男孩+女孩
egen child_num2=rowtotal(male_size2 female_size2)
// 删除重复样本
duplicates drop fid18, force
save "cfps2018famconf_202008.dta", replace
** 匹配数据
use "cfps2018famecon",clear
merge 1:1 fid18 using "cfps2018famconf_202008", keepusing(male_size2 female_size2 child_num2)
keep if _merge==3
drop _merge
save "cfps2018famecon",replace


************************ 面板数据的家庭子女数 ************************
** 考虑的问题：
** 1. 研究的年份范围
** 2. 你需要平衡面板还是非平衡面板
** 3. 家庭分户、家庭消亡问题——根据调查基期进行汇总数据——加总、求均值 —— 1)计算所需变量; 2)删除重复样本,筛选所需要变量; 3)append接驳(变量名一致性问题)——生成面板数据